T114 GPS Arduino Example

#1

Hi, Does anyone have a working example of getting GPS on a T114? Im trying the following without any success.

#EDIT - The example below works. It just took some reading to figure out all the pinouts. (serial2, vext, etc)

#include <TinyGPSPlus.h>
#include <Adafruit_TinyUSB.h> // for Serial

// The TinyGPSPlus object
TinyGPSPlus gps;

// GPS baud rate 
static const uint32_t GPSBaud = 9600;

void setup()
{
  Serial.begin(115200);
  while(!Serial) delay(10);   // Wait for Serial to be ready
  
  // Enable VEXT power
  pinMode(PIN_VEXT_CTL, OUTPUT);
  digitalWrite(PIN_VEXT_CTL, VEXT_ENABLE);
  delay(100); // Give power time to stabilize
  
  // Initialize Serial2 for GPS
  Serial2.begin(GPSBaud);

  Serial.println(F("GPS Test"));
  Serial.println(F("A simple demonstration of TinyGPSPlus with Heltec NRF52840 T114"));
  Serial.print(F("Testing TinyGPSPlus library v. ")); Serial.println(TinyGPSPlus::libraryVersion());
  Serial.println();
}

void loop()
{
  // This sketch displays information every time a new sentence is correctly encoded.
  while (Serial2.available() > 0)
    if (gps.encode(Serial2.read()))
      displayInfo();

  if (millis() > 5000 && gps.charsProcessed() < 10)
  {
    Serial.println(F("No GPS detected: check wiring."));
    Serial.println(F("Check if VEXT power is enabled and GPS is connected to pins 37(RX) & 39(TX)"));
    while(true);
  }
}

void displayInfo()
{
  Serial.print(F("Location: ")); 
  if (gps.location.isValid())
  {
    Serial.print(gps.location.lat(), 6);
    Serial.print(F(","));
    Serial.print(gps.location.lng(), 6);
  }
  else
  {
    Serial.print(F("INVALID"));
  }

  Serial.print(F("  Date/Time: "));
  if (gps.date.isValid())
  {
    Serial.print(gps.date.month());
    Serial.print(F("/"));
    Serial.print(gps.date.day());
    Serial.print(F("/"));
    Serial.print(gps.date.year());
  }
  else
  {
    Serial.print(F("INVALID"));
  }

  Serial.print(F(" "));
  if (gps.time.isValid())
  {
    if (gps.time.hour() < 10) Serial.print(F("0"));
    Serial.print(gps.time.hour());
    Serial.print(F(":"));
    if (gps.time.minute() < 10) Serial.print(F("0"));
    Serial.print(gps.time.minute());
    Serial.print(F(":"));
    if (gps.time.second() < 10) Serial.print(F("0"));
    Serial.print(gps.time.second());
    Serial.print(F("."));
    if (gps.time.centisecond() < 10) Serial.print(F("0"));
    Serial.print(gps.time.centisecond());
  }
  else
  {
    Serial.print(F("INVALID"));
  }

  Serial.println();
}